/\*

**These are the programs for reliability analyses and graphing.**

This is a big comment going over several lines.

NEVER put a quote mark or apostrophe in a comment.

\*/

/\*

**libname link to/from a directory for permanent SAS datasets**.

ss can be anything starting with a letter.

Get your directory structure as follows:

Find the Reliability models folder in Server Files and Folders.

Right-click it and select Properties.

Triple-click the Location window and copy to the clipboard.

Paste the clipboard to replace this text.

Make sure you have one quote mark around the directory, and semi-colon at the end.

\*/

libname ss "/folders/myfolders/Mixed-model Workshop/Reliability models/";

**\*filename link to import/export a spreadsheet;**

\*or just double-click on the Excel spreadsheet and let SAS do all the work;

\*xlsheet can be anything starting with a letter;

filename xlsheet "/folders/myfolders/Mixed-model Workshop/Reliability models/reliability data.xlsx";

**\*import a dataset** and call it games**;**

PROC IMPORT DATAFILE=xlsheet

OUT=games

DBMS=XLSX replace;

sheet='2-way long'; \*or whatever, or star off this line if there is only one sheet in the file;

attrib \_character\_ \_numeric\_ label="";

run;

**\*print the dataset;**

proc print data=games;

run;

**\*make a permanent dataset** called games;

data ss.games;

set games;

run;

**\*set up options for proc mixed output;**

ods noproctitle;

ods graphics / imagemap=on;

**title "One-way reliability analysis";**

proc mixed data=ss.games plots=StudentPanel alpha=0.1;

class AthleteID;

model LnDepVar= /residual;

random Intercept/subject=AthleteID;

\*random AthleteID; \*this does the same thing as the above line;

run;

**title "Two-way reliability analysis";**

\*import the spreadsheet 2-way long missing from the workbook reliability data.xlsx;

\*this program assumes the imported dataset is called IMPORT;

proc mixed data=IMPORT method=reml plots=(studentPanel) alpha=0.1;

class AthleteID GameID;

model LnDepVar= / solution cl alpha=0.1 alphap=0.1;

random Intercept / type=VC subject=AthleteID;

random GameID /;

run;

**title "Two-way reliability analysis with a fixed effect and nobound";**

\*this program assumes the imported dataset is called IMPORT;

proc mixed data=IMPORT method=reml plots=(studentPanel) alpha=0.1 nobound;

class AthleteID GameID LoseTieWin;

model LnDepVar=LoseTieWin / noint solution cl alpha=0.1;

random AthleteID GameID / solution cl alpha=0.1;

lsmeans LoseTieWin / diff alpha=0.1 cl;

run;

**\*plot the sets of sprints;**

\*Import the spreadsheet sets of reps long format.xlsx as IMPORT;

proc sort data=IMPORT;

by Set Rep;

title "Means and SDs";

proc means noprint data=IMPORT;

var Time;

by Set Rep Xaxis;

output out=meantime n=NoOfSprints mean=TimeMean std=TimeSD min=TimeMin max=TimeMax;

proc print data=meantime noobs;

var Set Rep Xaxis NoOfSprints TimeMean TimeSD TimeMin TimeMax;

format TimeMean TimeSD TimeMin TimeMax 6.1;

run;

data meantime1;

set meantime;

MeanPlusSD=TimeMean+TimeSD;

MeanMinusSD=TimeMean-TimeSD;

run;

title height=1.5 "Means and SDs, series side-by-side";

ods graphics / reset width=16cm height=20cm imagemap attrpriority=none;

proc sgplot data=meantime1 noborder;

styleattrs

datacolors=(black blue red green)

datalinepatterns=(solid)

datacontrastcolors=(black)

datasymbols=(circlefilled squarefilled diamondfilled trianglefilled);

\*reg x=Xaxis y=TimeMean /degree=1 nomarkers lineattrs=(thickness=1) group=Set;

\*scatter x=Xaxis y=TimeMean /yerrorupper=MeanPlusSD yerrorlower=MeanMinusSD

errorbarattrs=(color=black) group=Set

filledoutlinedmarkers markerattrs=(size=18) name='abc';

\*unstar the above two lines and star off the next two lines to fit regression polynomials;

scatter x=Xaxis y=TimeMean /yerrorupper=MeanPlusSD yerrorlower=MeanMinusSD

errorbarattrs=(color=black) group=Set;

series x=Xaxis y=TimeMean /markers filledoutlinedmarkers markerattrs=(size=18)

lineattrs=(pattern=solid) group=set name='abc';

keylegend 'abc' /title="Set:" noborder titleattrs=(size=16) valueattrs=(size=16);

xaxis label="Repetition+10\*Set" labelattrs=(size=16) valueattrs=(size=16);

yaxis label="Sprint time (s)" labelpos=top labelattrs=(size=16) valueattrs=(size=16);

\*refline 0;

run;

ods graphics / reset;

title height=1.5 "Means and SDs, series overlapping";

ods graphics / reset width=16cm height=20cm imagemap attrpriority=none;

\*proc sgplot data=meantime1 noborder uniform=all;

\*by Set;

\*unstar the above two lines and star off the next to get separate graphs for animation;

proc sgplot data=meantime1 noborder;

styleattrs

datacolors=(black blue red green)

datalinepatterns=(solid)

datacontrastcolors=(black)

datasymbols=(circlefilled squarefilled diamondfilled trianglefilled);

\*reg x=Rep y=TimeMean /degree=1 nomarkers lineattrs=(thickness=1) group=Set;

\*scatter x=Rep y=TimeMean /yerrorupper=MeanPlusSD yerrorlower=MeanMinusSD

errorbarattrs=(color=black) groupdisplay=cluster clusterwidth=0.4 group=Set

filledoutlinedmarkers markerattrs=(size=18) name='abc';

\*unstar the above two lines and star off the next two lines to fit regression polynomials;

scatter x=Rep y=TimeMean /yerrorupper=MeanPlusSD yerrorlower=MeanMinusSD

errorbarattrs=(color=black) groupdisplay=cluster clusterwidth=0.4 group=Set;

series x=Rep y=TimeMean /markers filledoutlinedmarkers markerattrs=(size=18)

lineattrs=(pattern=solid) groupdisplay=cluster clusterwidth=0.4 group=set name='abc';

keylegend 'abc' /title="Set:" noborder titleattrs=(size=16) valueattrs=(size=16);

xaxis label="Sprint number" labelattrs=(size=16) valueattrs=(size=16)

values=(1 to 6 by 1) offsetmin=0.1 offsetmax=0.06;

yaxis label="Sprint time (s)" labelpos=top labelattrs=(size=16) valueattrs=(size=16);

\*refline 0;

run;

ods graphics / reset;

**\*analysis of sets of sprints;**

\*import sets of sprints long format.xlsx as IMPORT before running the mixed model;

data sprints;

set IMPORT;

RepRescaled=(Rep-1)/5-0.5;

run;

title "Random slopes model for analysis of sets of sprints";

proc mixed data=sprints plots=(studentPanel) alpha=0.1 nobound;

class Athlete Set;

model LnTime=Set RepRescaled\*Set xVarRep6 / solution cl alpha=0.1;

random Intercept RepRescaled / type=UN subject=Athlete;

random Set xVarRep6 / subject=Athlete;

lsmeans Set / diff alpha=0.1 cl;

run;

**\*simple mixed model for two levels of repeated measurement;**

\*model, random and lsmean statements for several repeated measurements within several sets;

model Whatever=Set/solution cl alpha=0.1;

random Athlete Athlete\*Set;

lsmeans Set/diff cl alpha=0.1;